Reading a Soft Potentiometer — SIK Circuit 10

/*
SparkFun Inventor's Kit
Example sketch 10 — SOFT POTENTIOMETER

Use the soft potentiometer to change the color of the RGB LED.

Hardware connections:
  Soft pot: middle pin to analog 0, one side to 5V, other to GND
  10K resistor from analog 0 to GND
  RGB LED: RED->330ohm->pin 9, COMMON->GND, GREEN->330ohm->pin 10, BLUE->330ohm->pin 11

This code is completely free for any use.
*/

const int RED_LED_PIN = 9;
const int GREEN_LED_PIN = 10;
const int BLUE_LED_PIN = 11;

const int SENSOR_PIN = 0;

int redValue, greenValue, blueValue;

void setup()
{
  // No setup needed
}

void loop()
{
  int sensorValue;
  sensorValue = analogRead(SENSOR_PIN);
  setRGB(sensorValue);
}

void setRGB(int RGBposition)
{
  int mapRGB1, mapRGB2, constrained1, constrained2;

  // Red peak, centered at 0
  mapRGB1 = map(RGBposition, 0, 341, 255, 0);
  constrained1 = constrain(mapRGB1, 0, 255);
  mapRGB2 = map(RGBposition, 682, 1023, 0, 255);
  constrained2 = constrain(mapRGB2, 0, 255);
  redValue = constrained1 + constrained2;

  // Green peak, centered at 341
  greenValue = constrain(map(RGBposition, 0, 341, 0, 255), 0, 255)
             - constrain(map(RGBposition, 341, 682, 0, 255), 0, 255);

  // Blue peak, centered at 682
  blueValue = constrain(map(RGBposition, 341, 682, 0, 255), 0, 255)
            - constrain(map(RGBposition, 682, 1023, 0, 255), 0, 255);

  analogWrite(RED_LED_PIN, redValue);
  analogWrite(GREEN_LED_PIN, greenValue);
  analogWrite(BLUE_LED_PIN, blueValue);
}