Driving a Motor — SIK Circuit 12

/*
SparkFun Inventor's Kit
Example sketch 12 — SPINNING A MOTOR

Use a transistor to spin a motor at different speeds.

Hardware connections:
  Transistor BASE through 330 ohm resistor to digital pin 9
  Transistor EMITTER to GND
  Transistor COLLECTOR to motor black wire
  Motor red wire to 5V
  Flyback diode: band (cathode) to 5V, anode to motor black wire

This code is completely free for any use.
*/

const int motorPin = 9;

void setup()
{
  pinMode(motorPin, OUTPUT);
  Serial.begin(9600);
}

void loop()
{
  serialSpeed();

  //motorOnThenOff();
  //motorOnThenOffWithSpeed();
  //motorAcceleration();
}

void serialSpeed()
{
  int speed;

  Serial.println("Type a speed (0-255) into the box above,");
  Serial.println("then click [send] or press [return]");
  Serial.println();

  while(true)
  {
    while (Serial.available() > 0)
    {
      speed = Serial.parseInt();
      speed = constrain(speed, 0, 255);

      Serial.print("Setting speed to ");
      Serial.println(speed);

      analogWrite(motorPin, speed);
    }
  }
}

void motorOnThenOff()
{
  int onTime = 3000;
  int offTime = 3000;

  digitalWrite(motorPin, HIGH);
  delay(onTime);
  digitalWrite(motorPin, LOW);
  delay(offTime);
}

void motorOnThenOffWithSpeed()
{
  int Speed1 = 200;
  int Time1 = 3000;
  int Speed2 = 50;
  int Time2 = 3000;

  analogWrite(motorPin, Speed1);
  delay(Time1);
  analogWrite(motorPin, Speed2);
  delay(Time2);
}

void motorAcceleration()
{
  int speed;
  int delayTime = 20;

  for(speed = 0; speed <= 255; speed++)
  {
    analogWrite(motorPin, speed);
    delay(delayTime);
  }
  for(speed = 255; speed >= 0; speed--)
  {
    analogWrite(motorPin, speed);
    delay(delayTime);
  }
}